sub Start ( \
       byval Registration as string, \
       byval Copyright    as string )
     //////////////////////////////////////////////////////////////////////
       dim Cost as integer
       dim Time_Added as integer
       dim FileRec as FileRecord
       dim Log_Str as string
     //////////////////////////////////////////////////////////////////////
       Cost = 1
       if ParamCount >= 1 then
         Cost = Val ( ParamStr ( 1 ) )
       end if

       Time_Added = 30
       if ParamCount >= 2 then
         Time_Added = Val ( ParamStr ( 2 ) )
       end if

       Log_Str = "Buy Time:  $" + FormatNumber ( Cost / 100, "@##.##" ) \
         + " for " + FormatNumber ( Time_Added, "@####" ) + " minutes"

       cls
       Color ( 10 )
       ? Copyright
       ? "Registration:  "; Registration
       ?
       Color ( 11 )
       ? "You have ";
       Color ( 12 )
       ? TimeLeft;
       ? " minutes ";
       Color ( 11 )
       ? "left."
       ? "You have ";
       Color ( 10 )
       ? "$";
       ? Trim ( FormatNumber ( User.SubscriptionBalance / 100, "###.##" ) );
       Color ( 11 )
       ? " in your account balance."
       ?
       Color ( 12 )
       ? Time_Added;
       ? " minutes ";
       Color ( 11 )
       ? "may be added to your online time for this session for ";
       Color ( 10 )
       ? "$";
       ? Trim ( FormatNumber ( Cost / 100, "###.##" ) );
       Color ( 11 )
       ? "."
       ?
       if User.SubscriptionBalance >= Cost then
         if InputYesNo ( "Would you like to buy some time? (y/N):  ", \
           false ) then
             AddTime ( Time_Added )
             User.SubscriptionBalance = User.SubscriptionBalance - Cost
             ? "Done!"
             ActivityLog ( Log_Str )
         else
           ? "Time not purchased."
         end if
       else
         ? "Please contact your System Operator (SysOp) to increase your ";
         ? "account balance."
       end if
       WaitEnter
     end sub