// ForwardUtil - Lets users set up an e-mail forwarding address
// to forward incoming e-mail to.  It can forward e-mail to both
// local and Internet addresses
//
// By: Pete Nelson (pete@terminal-one.com)
// v1.01 (03/07/96)



type forward_rec
   name as string*30
   address as string*70
   fwd_on as string*1
   delete_msg as string*1
end type


dim forward as forward_rec
dim choice as string
dim local_yn as string, inet_yn as string

if not exists("3rdparty\forward\fwd.cfg") then
   print
   print "@0C@FWD.CFG not found!"
   print
   waitenter
   end
end if

open "3rdparty\forward\fwd.cfg" for input as #1
input #1, local_yn
input #1, inet_yn
input #1, inet_yn
close

local_yn = trim(ucase(local_yn))
inet_yn = trim(ucase(inet_yn))


open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
get #1, user.userid, forward

if forward.name <> user.name then
   forward.name = user.name
   forward.address = ""
   forward.fwd_on = "N"
   forward.delete_msg = "N"
   put #1, user.userid, forward
end if
close


main_menu:
cls
print
print " @0D@- @0B@E-Mail Forwarding System @0D@-"
print
print "WARNING:  currently, mail is only forwarded from conferences"
print "1 and 2.  If you want the other conferences supported for"
print "forward, send your request along with a donation to the BBS."
print "-- David Croft"
print
print " @0E@Forwarding is@07@: @0F@";
if forward.fwd_on = "Y" then print "Active"
if forward.fwd_on = "N" then print "Not Active"
print " @0E@Forwarding to@07@: @0F@" forward.address
print " @0E@Delete Msgs  @07@: @0F@" forward.delete_msg
print
print " @09@[@0F@T@09@] @0E@- @0A@Toggle Forwarding Off/On"
print " @09@[@0F@C@09@] @0E@- @0A@Change Forwarding Address"
print " @09@[@0F@D@09@] @0E@- @0A@Toggle Message Deletion"
print " @09@[@0F@H@09@] @0E@- @0A@Help"
print " @09@[@0F@Q@09@] @0E@- @0A@Quit"
print
print " @0B@Choice@07@: " ;


do
   choice = ucase(inkey)
loop until choice > ""

select case choice
   case "T"
      if forward.fwd_on = "Y" then 
         forward.fwd_on = "N"
      else
         if trim(forward.address) <> "" then
            forward.fwd_on = "Y"
         else
            print
            print
            print "@0C@You can not activate forwarding when your forwarding address is blank."
            print
            waitenter
            goto main_menu
         end if
      end if
      open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
      put #1, user.userid, forward
      close
      goto main_menu
   
   case "D"
      if forward.delete_msg = "Y" then 
         forward.delete_msg = "N"
      else
         forward.delete_msg = "Y"
      end if
      open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
      put #1, user.userid, forward
      close
      goto main_menu

   case "C"
      print
      print
      print "@0A@Enter e-mail address to forward to@07@:" defcolor
      forward.address = inputmask("","XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX",forward.address)
      forward.address = trim(forward.address)
      if forward.address = "" and forward.fwd_on = "Y" then
         print
         print "@0C@You can not remove your forwarding address when forwarding is active."
         print
         waitenter
         open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
         get #1, user.userid, forward
         close
         goto main_menu
      end if

      if instr(forward.address," ") > 0 and local_yn = "N" then
         print
         print "@0C@E-mail forwarding to local addresses not supported."
         print
         waitenter        
         open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
         get #1, user.userid, forward
         close
         goto main_menu
      end if

      if instr(forward.address,"@") > 0 and inet_yn = "N" then
         print
         print "@0C@E-mail forwarding to Internet addresses not supported."
         print
         waitenter
         open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
         get #1, user.userid, forward
         close
         goto main_menu
      end if


      open "3rdparty\forward\fwd.dat" for random as #1 len = len(forward_rec)
      put #1, user.userid, forward
      close
      goto main_menu

   case "H"
      goto help

   case "Q"
      print
      end

   case else
      goto main_menu
end select

     



help:

cls
print
print " @0E@Forwarding is@07@: @0F@Active/Not Active"
print "   @07@-@0B@Changes whether or not message forwarding is active for your mail."
print " @0E@Forwarding to@07@: @0F@"
print "   @07@-@0B@E-Mail address where mail will be forwarded to."
print " @0E@Delete Msgs  @07@: @0F@" forward.delete_msg
print "   @07@-@0B@Changes whether or not the original e-mail will deleted when forwared."
print
waitenter
goto main_menu